pluginManagement {
    repositories {
        maven { url "https://maven.fabricmc.net/" }
        maven { url "https://maven.kikugie.dev/releases" }
        gradlePluginPortal()
        mavenCentral()
    }
}

plugins {
    id "dev.kikugie.stonecutter" version "0.9.8"
}

rootProject.name = "saturn-client"

include("common")

// Versions built by Stonecutter from the shared src/ (see stonecutter.gradle). Each one's
// versions/<v>/gradle.properties holds its Minecraft, Yarn and Fabric API versions.
def stonecutterVersions = ["1.21.11"]

stonecutter {
    kotlinController = false     // stonecutter.gradle configures the root project
    centralScript = "build.gradle" // build.gradle configures each version
    create(rootProject) {
        versions(*stonecutterVersions)
        vcsVersion = "1.21.11"
    }
}

// Versions not moved to Stonecutter yet still build from their own copy in versions/<v>/src,
// as projects named mc-<v>.
file("versions").eachDir { dir ->
    if (dir.name in stonecutterVersions) {
        return
    }
    def projectName = "mc-${dir.name}"
    include(projectName)
    project(":${projectName}").projectDir = dir
}