pluginManagement {
    repositories {
        maven("https://maven.fabricmc.net/")
        maven("https://maven.kikugie.dev/releases")
        gradlePluginPortal()
        mavenCentral()
    }
}

plugins {
    // Downloads the Java toolchain a version needs (Java 25 for 26.1+) when it isn't installed.
    id("org.gradle.toolchains.foojay-resolver-convention") version "1.0.0"
    id("dev.kikugie.stonecutter") version "0.9.8"
    // Picks the Loom variant per version: remapping for 1.21.x, plain for the unobfuscated 26.1+.
    // Its version is loomx.loom_version in gradle.properties.
    id("dev.kikugie.loom-back-compat") version "0.4.2"
}

rootProject.name = "saturn-client"

include("common")

// Versions built by Stonecutter from the shared src/ (see stonecutter.gradle.kts). Each one's
// versions/<v>/gradle.properties holds its Minecraft, Fabric Loader and Fabric API versions.
val stonecutterVersions = listOf(
    "1.21.4", "1.21.5", "1.21.6", "1.21.7", "1.21.8", "1.21.9", "1.21.10", "1.21.11",
    "26.1", "26.2", "26.3",
)

stonecutter {
    create(rootProject) {
        versions(stonecutterVersions)
        vcsVersion = "1.21.11"
    }
}