pluginManagement {
    repositories {
        maven("https://maven.fabricmc.net/")
        maven("https://maven.kikugie.dev/releases")
        gradlePluginPortal()
        mavenCentral()
    }

    // Loom's version, for the Stonecutter versions' build.gradle.kts (the old mc-<v> projects set
    // their own in versions/<v>/gradle.properties).
    val loom_version: String by settings
    plugins {
        id("net.fabricmc.fabric-loom-remap") version loom_version
    }
}

plugins {
    id("dev.kikugie.stonecutter") version "0.9.8"
}

rootProject.name = "saturn-client"

include("common")

// Versions built by Stonecutter from the shared src/ (see stonecutter.gradle.kts). Each one's
// versions/<v>/gradle.properties holds its Minecraft, Yarn and Fabric API versions.
val stonecutterVersions = listOf("1.21.7", "1.21.8", "1.21.9", "1.21.10", "1.21.11")

stonecutter {
    create(rootProject) {
        versions(stonecutterVersions)
        vcsVersion = "1.21.11"
    }
}

// Versions not moved to Stonecutter yet still build from their own copy in versions/<v>/src,
// as projects named mc-<v>.
file("versions").listFiles { file -> file.isDirectory && file.name !in stonecutterVersions }!!
    .sortedBy { it.name }
    .forEach { dir ->
        include("mc-${dir.name}")
        project(":mc-${dir.name}").projectDir = dir
    }